liczenie głosów

[neisej]

Przy "Forumowy Top Wszech Czasów 2023" pojawił się wątek o liczeniu głosów (viewtopic.php?p=762277#p762277) więc przydałoby się go wydzielić. Dodam zaraz kilka postów które później będę uzupełniane na podstawie rozmów poniżej
P.S. Nie wiem czy to jest dobre miejsce na takie coś ale nic lepszego nie widzę

[neisej]

z forum do arkusza

Do łatwiejszego kopiowania z forum do arkusza wspieram się edytorem Notepad++ (https://notepad-plus-plus.org/downloads/) są też pewnie inne ale chodzi o to by obsługiwało 'wyrażenia regularne'.

głosy jednej osoby
1. Kopiuję wszystkie głosy (np. viewtopic.php?p=755252#p755252)
2. Wklejam do tego edytora
3. Wciskam Ctrl+H (Znajdź i zamień)
3a. Upewniam się, że Tryb szukania jest ustawiony na "Wyrażenia regularne".
4. W znajdź wklejam

Kod: Zaznacz cały

[\r\n\s]*^(\d+)[\.,]?\s*

(znajdzie to na początku każdego wiersza

^

(poprzedzonymi opcjonalnie znakami nowej linii czy białymi znakami

[\r\n\s]*

) numer

(\d+)

potem opcjonalną kropkę lub przecinek

[\.,]?

, a potem opcjonalny odstęp (spacje, tabulatory i inne białe znaki)

\s*

)
5. W zamień wkejam

Kod: Zaznacz cały

\r\n\1\t

(podmieni znaleziony fragment na pojedynczą nową linię

\r\n

, znalezioną liczbę czyli zawartość pierwszego nawiasu okrągłego

\1

a potem doda tabulator

\t

tak by arkusz widział to jako 2 kolumny)
6. Wciskam Zamień wszystko (mam teraz te informacje w 2 "kolumnach": pozycja i utwór)
7. (opcjonalnie) Z menu wybieram Edycja > Operacje na liniach > Sortowanie linii rosnąco jak liczby (po angielsku: Edit > Line Operations > Sort Lines As Integers Ascending) aby posortować linie w.g. numerów i pozbyć się pustych linii pomiędzy. Ale problem jest taki, że wtedy zakładamy, że numer ważniejszy jest niż wypisana kolejność.
8. Zaznaczam wszystko i wklejam do arkusza w którym mam teraz pozycję i utwór w osobnych kolumnach (A i B)
9. W nowej kolumnie (C) do każdego wiersza z tego zestawu wklejam nazwę użytkownika

wyniki głosowania
1. Najpierw pobierz wszystkie pozycje z głosowania i wklej je do nowego pliku w Notepad++.
Pierwszą linię zostaw pustą. Pozostałe puste linie nie mają znaczenia.
2. Po otwarciu komendy "Znajdź i zamień" użyj poniższych wartości:
Znajdź:

Kod: Zaznacz cały

\s*(?:\(([+\-]\d+|N+)\))?(?:\r\n)+(\d+)\.\s*\[(\d+)\s*\|\s*(\d+)\s*\|\s*(\d+)\s*x\s*(\d+)\.s*\]\s*(.+?)\s*(?:\(([+\-]?\d+|N+)\)\s*(\([\w,\s]+\))?\s*(?:[\s\n\r]+(https://.+)))?$

<pierwsza wersja>
Zamień:

Kod: Zaznacz cały

\r\n\7\t\3\t\4\t\6\t\5\t\9\t\t\2\t\t\8\t$10

<druga wersja>
3. Wklej wynik do osobnego arkusza z wynikami np. Top2022wyniki. Teraz wyniki powinny być w kolumnach takich jak w arkuszu z wynikami głosowania (czyli: utwór, punkty, ilość głosów, najwyższa pozycja, ile razy najwyższa pozycja, kto głosował na najwyższą pozycję, punkty rozszerzone, pozycja, poprzednia pozycja, zmiana pozycji, link)
4. Po pobraniu tych wyników (z poprzedniego roku) trzeba dodać tam nowości na liście propozycji z obecnego roku i jako pozycję dopisać "NN" i ewentualnie dopisać linki do tych pozycji których brakuje a przy prezentacji powinny mieć linki.
Uwaga 2: Sprawdzane było na wynikach z Forumowy Top Wszech Czasów 2022. posty od viewtopic.php?p=734442#p734442 do viewtopic.php?p=734505#p734505
Uwaga 1: Jest problem z pozycjami poniżej 100 bo tam od razu po nazwie utworu podani są czasami użytkownicy, których to był numer 1 ale te polecenia ich nie rozdzielają czyli trzeba to ręcznie znaleźć i w arkuszu poprawić.

[neisej]

arkusz z wszystkimi głosami

Nazwa arkusza: Top2023glosy

Pierwszy wiersz z nazwami kolumn (same nazwy mogą być inne - nie mają wpływu na formuły):
Kolumna A: pozycja
Kolumna B: utwór
Kolumna C: osoba
Kolumna D: punkty
Kolumna E: czy duplikaty utworu
Kolumna F: czy prawidłowa nazwa utworu
Kolumna G: sugerowana pozycja
Kolumna H: ile głosów osoby
Kolumna I: brakująca suma pozycji osoby
Kolumna J: sugerowana pozycja 2
Kolumna K: czy błąd pozycji
Kolumna L: -
Kolumna M: utwór ustandaryzowany
Kolumna N: pozycja utworu na liście wyników
Kolumna O: sugestia tytułu 1
Kolumna P: sugestia tytułu 2 (jeśli nie znalezione to wcześniejsze dopasowanie)
Kolumna Q: sugestia tytułu 3 (jeśli nie znalezione to następne dopasowanie

Kolumny A B C wypełnione ręcznie (patrz post wcześniejszy)

Kolejne kolumny wypełnione formułami w wierszu 2 a potem przekopiowane na pozostałe wiersze poniżej.

Kolumna D:

Kod: Zaznacz cały

=101-A2

Kolumna E:

Kod: Zaznacz cały

=JEŻELI(LICZ.WARUNKI($B$2:B2;B2;$C$2:C2;C2)>1; "Duplikat"; "")

Kolumna F:
LibreOffice7.5:

Kod: Zaznacz cały

=PODAJ.POZYCJĘ(B2;Top2023wyniki.A:A;0)

Excel, Google:

Kod: Zaznacz cały

=PODAJ.POZYCJĘ(B2;Top2023wyniki!A:A;0)

Wtedy błąd (#N/D) oznacza, że utworu nie ma na liście lub jest jakaś literówka. Niestety każdy utwór trzeba sprawdzić ręcznie

Kolumna G:

Kod: Zaznacz cały

=JEŻELI(C2=C1;JEŻELI(CZY.LICZBA(G1);JEŻELI(A2=G1+1;"";G1+1);JEŻELI(A2=A1+1;"";A1+1));JEŻELI(A2=1;"";1))

Jeśli jest błąd to wyświetla oczekiwany numer pozycji. (powinno być, że pierwszy głos osoby powinien być 1 a kolejne to o 1 więcej niż poprzedni (oczekiwany lub rzeczywisty))
Może być problem gdy jest za mało głosów i trzeba obniżyć pozycję, ale wtedy można dodać wiersz z pustym utworem i powinno być OK)

Kolumna H:

Kod: Zaznacz cały

=LICZ.JEŻELI(C:C;C2)

Liczy ilość głosów danej osoby. Powinno być 100

Kolumna I:

Kod: Zaznacz cały

=5050-SUMA.JEŻELI(C:C;C2;A:A)

Z sumowania prawidłowych pozycji od 1 do 100 wychodzi liczba 5050. W tej kolumnie wyświetlane będzie brakująca ilość z sumowania pozycji głosów danej osoby.

Kolumna J:

Kod: Zaznacz cały

=LICZ.JEŻELI(C$2:C2;C2)

Kolumna K:

Kod: Zaznacz cały

=JEŻELI(A2=J2;"";"BŁĄD")

Kolumna L:

Kod: Zaznacz cały

Kolumna M:

Kod: Zaznacz cały

=REGEX(REGEX(REGEX(OCZYŚĆ(PODSTAW(PODSTAW(LITERY.MAŁE(B2);"é";"e");"ł";"l"));" (&|\+|feat\.?|and) ";" i ";"g");"[^a-z0-9 ]|^the | the ";"";"g");" ";"";"g")

Kolumna N:

Kod: Zaznacz cały

=PODAJ.POZYCJĘ(M2;Top2023wyniki.M:M;0)

Kolumna O:

Kod: Zaznacz cały

=INDEKS(Top2023wyniki.A:A;N2)

Kolumna P:

Kod: Zaznacz cały

=INDEKS($TMP3wyniki.A:A;PODAJ.POZYCJĘ(M2;Top2023wyniki.M:M;1))

Kolumna Q:

Kod: Zaznacz cały

=INDEKS($TMP3wyniki.A:A;PODAJ.POZYCJĘ(M2;Top2023wyniki.M:M;1)+1)

[neisej]

arkusz z wynikami głosowania

Nazwa arkusza: Top2023wyniki

Pierwszy wiersz z nazwami kolumn (same nazwy mogą być inne - nie mają wpływu na formuły):
Kolumna A: utwór
Kolumna B: punkty
Kolumna C: ilość głosów
Kolumna D: najwyższa pozycja
Kolumna E: ile razy najwyższa pozycja
Kolumna F: kto głosował na najwyższą pozycję
Kolumna G: punkty rozszerzone
Kolumna H: pozycja
Kolumna I: poprzednia pozycja
Kolumna J: zmiana pozycji
Kolumna K: link
Kolumna L: wpis na forum
Kolumna M: utwór ustandaryzowany

Kolumna Y: debiut/pierwszy głos
Kolumna Z: ranking miejsc
Kolumny AA-DV: liczby od 1 do 100



Kolumna A uzupełniana ręcznie wszystkimi utworami na które można było głosować.

Kolejne kolumny wypełnione formułami w wierszu 2 a potem przekopiowane na pozostałe wiersze poniżej.
UWAGA: LibreOffice (7.5) po nazwie arkusza ma kropkę zamiast wykrzyknika.

Kolumna B:
google:

Kod: Zaznacz cały

=SUMA.JEŻELI(Top2023glosy!B:B;A2;Top2023glosy!D:D)

libreOffice:

Kod: Zaznacz cały

=SUMA.JEŻELI(Top2023glosy.B:B;A2;Top2023glosy.D:D)

Kolumna C:
google:

Kod: Zaznacz cały

=LICZ.JEŻELI(Top2023glosy!B:B;A2)

libreOffice:

Kod: Zaznacz cały

=LICZ.JEŻELI(Top2023glosy.B:B;A2)

Kolumna D:
google:

Kod: Zaznacz cały

=MINIFS(Top2023glosy!A:A;Top2023glosy!B:B;A2)

libreOffice:

Kod: Zaznacz cały

=MIN.WARUNKÓW(Top2023glosy.A:A;Top2023glosy.B:B;A2)

Kolumna E:
google:

Kod: Zaznacz cały

=LICZ.WARUNKI(Top2023glosy!B:B;A2;Top2023glosy!A:A;D2)

libreOffice:

Kod: Zaznacz cały

=LICZ.WARUNKI(Top2023glosy.B:B;A2;Top2023glosy.A:A;D2)

Kolumna F:
google:

Kod: Zaznacz cały

=join(", ";FILTER(Top2023glosy!C:C;Top2023glosy!B:B=A2;Top2023glosy!A:A=D2))

libreOffice:

Kod: Zaznacz cały

=POŁĄCZ.TEKSTY(", ";1;JEŻELI((LITERY.MAŁE(Top2023glosy.B:B)=LITERY.MAŁE(A2))*(Top2023glosy.A:A=D2);Top2023glosy.C:C;""))

tylko w przypadku LibreOffice to jest trochę bardziej skomplikowane bo:

• Po wklejeniu tej formuły do komórki A2 trzeba oznaczyć ją jako funkcja macierzowa (teoretycznie działa Ctrl+Shift+Enter ale nie u mnie. Musiałem wcisnąć przycisk funkcji i w edytorze w lewym dolnym rogu jest checkbox "Macierz", który trzeba zaznaczyć przed potwierdzeniem funkcji).

• Kopiując formułę do wszystkich (1007) wierszy program mi się zawiesił.

(ale w formacie komórki, zakładka "Wyrównanie" można odznaczyć dla tej kolumny "Zawijaj tekst automatycznie" to może kopiowanie będzie szybciej zrobione

Kolumna G:

Kod: Zaznacz cały

="z"&TEKST(B2;"000000")&TEKST(C2;"0000")&TEKST(100-D2;"00")&TEKST(E2;"000")&Z2&TEKST(9999-JEŻELI(CZY.LICZBA(I2);I2;0);"0000")&TEKST(999999-Y2;"000000")

dla kolejności kryteriów (np. dla pojedynczego notowania): punkty, ilość głosów, najwyższa pozycja, ile razy najwyższa pozycja, ranking miejsc, poprzednie miejsce, pierwszy głos

Kod: Zaznacz cały

="z"&TEKST(B2;"000000")&TEKST(100-D2;"00")&TEKST(E2;"000")&TEKST(C2;"0000")&Z2&TEKST(999999-Y2;"000000")

dla kolejności kryteriów (np. dla podsumowania notowań): punkty, najwyższa pozycja, ile razy najwyższa pozycja, ilość notowań/głosów, ranking miejsc, debiut

Kod: Zaznacz cały

=WARTOŚĆ(TEKST(B2;"000000")&TEKST(C2;"00")&TEKST(100-D2;"00")&TEKST(E2;"00"))

dla kolejności kryteriów (np. dla pojedynczego notowania): punkty, ilość głosów, najwyższa pozycja, ile razy najwyższa pozycja

Kod: Zaznacz cały

=WARTOŚĆ(TEKST(B2;"000000")&TEKST(100-D2;"00")&TEKST(E2;"00")&TEKST(C2;"00"))

dla kolejności kryteriów: punkty najwyższa pozycja, ile razy najwyższa pozycja, ilość głosów

Kolumna H:

Kod: Zaznacz cały

=1+LICZ.JEŻELI(G:G;">"&G2)

dla formuł z kolumny G rozpoczynających się literą:

Kod: Zaznacz cały

=POZYCJA(G2;G:G;FAŁSZ())

dla formuł z kolumny G rozpoczynających się do formuły 'WARTOŚĆ'

Kolumna I:
libreOffice:

Kod: Zaznacz cały

=WYSZUKAJ.PIONOWO(A2;Top2022wyniki.A:H;8;FAŁSZ())

Uwaga: kolumny I, K wymagają by w arkuszu Top2022wyniki były nie tylko wyniki z poprzedniego notowania ale też nowości w propozycjach z obecnego z pozycją wpisaną jako "NN"

Kolumna J:

Kod: Zaznacz cały

=JEŻELI(I2="NN";"NN";I2-H2)

Kolumna K:
libreOffice:

Kod: Zaznacz cały

=WYSZUKAJ.PIONOWO(A2;Top2022wyniki.A:K;11;FAŁSZ())

Kolumna L:
libreOffice:

Kod: Zaznacz cały

=JEŻELI(H2<=3;"[b][size=200]";JEŻELI(H2<=6;"[b][size=150]";JEŻELI(H2<=9;"[b][size=125]";JEŻELI(H2<=100;"[b][size=100]";""))))
&JEŻELI(CZY.LICZBA(I2);JEŻELI(I2-H2<0;"[color=#FF0000]";JEŻELI(I2=H2;"[color=#000080]";"[color=#008000]"));"[color=#BF4080]")
&H2
&". ["
&B2
&" | "
&C2
&" | "
&E2
&" x "
&D2
&".] "
&A2
&" ("
&JEŻELI(CZY.LICZBA(I2);JEŻELI(I2-H2<0;"";"+")
&I2-H2;I2)
&")[/color]"
& JEŻELI(D2=1;" [size=125]("
&P2
&")[/size]";"")
&JEŻELI(CZY.BRAK(K2);"";JEŻELI(K2<>"";" "
&K2;""))
&JEŻELI(H2<=100;"[/b][/size]";"")

Kolumna M:
libreOffice:

Kod: Zaznacz cały

=REGEX(REGEX(REGEX(OCZYŚĆ(PODSTAW(PODSTAW(LITERY.MAŁE(A2);"é";"e");"ł";"l"));" (&|\+|feat\.?|and) ";" i ";"g");"[^a-z0-9 ]|^the | the ";"";"g");" ";"";"g")

Kolumna Y:

Kod: Zaznacz cały

=PODAJ.POZYCJĘ(A2;Top2023glosy.B:B;0)

Kolumna Z:

Kod: Zaznacz cały

=POŁĄCZ.TEKSTY("";1;AA2:DV2)

Kolumna AA:

Kod: Zaznacz cały

=TEKST(LICZ.WARUNKI(Top2023glosy.$B:$B;$A2;Top2023glosy.$A:$A;AA$1);"00")

I tą formułę trzeba przeciągnąć (skopiować) do kolumny DV i potem cały wiersz przeciągnąć (skopiować) na pozostałe wiersze.
Ważne by w pierwszym wierszu były liczby od 1 do 100 np. AA1 = 1; AB1 = 2; ...; DV1 = 100


Wersja pierwsza, pewnie do poprawy z powodu braku kolumny z listą osób głosujących jako najwyżej ta informacja się tu jeszcze nie będzie wyświetlać.

[neisej]

statystyki

<uzupełniane będzie później>

[neisej]

inne

<uzupełniane będzie później>

[mario85832719]

Ściągnąłem sobie ten program, rozdzieliłem lokaty od nazwy wykonawcy i utworu, skopiowałem to wszystko do arkusza LibreOffice Calc 7.6 i w kolumnie A mam teraz lokaty, w kolumnie B nazwę utworu, w kolumnie C od góry do samego dołu nazwę konta forumowicza, w kolumnie D wpisałem w drugim wierszu tę formułę, rozciągnąłem na całą kolumnę i pojawiły mi się punkty od 100 do 1. Szybko i sprawnie. Ale co dalej? Bo to dopiero głosowanie jednego forumowicza. Jestem ciekawy w jaki sposób później można połączyć te wszystkie pojedyńcze wyniki w całość. I jak w ogóle jakwychwyciłeś, że jakiegoś utworu nie było w zestawie do głosowania i że były zdublowane głosy, bo na razie to jest przypisywanie punktów za lokaty w automacie.

[neisej]

Pozostałe głosy pozostałych użytkowników trzeba dopisać pod spodem
A jak się ten arkusz z głosami nazywa?

W drugim arkuszu tego samego dokumentu, gdzie będą wyniki, trzeba wkleić wszystkie utwory na które można było głosować i potem skorzystać z funkcji jak w poście wyniki (viewtopic.php?p=762627#p762627)

[neisej]

Teraz do zrobienia będzie dodanie funkcji do wyliczenia pozycji utworu, a potem sprawdzenie czy są duplikaty i czy utwory w głosach są poprawne tzn. czy są dokładnie identyczne co do znaku z tymi z listy wszystkich utworów. Ale to jak będę mieć troche czasu to napiszę.

[mario85832719]

Słuchaj, postanowiłem wszystko zrobić po kolei i to wszystko na teraz wygląda tak: w pierwszym arkuszu, który nazwałem tak jak Ty, czyli Top2023glosy w kolumnie A od komórki A2 w dół do komórki A101 są lokaty od 1 do 100, w kolumnie B od komórki B2 w dół do komórki B101 są nazwy wykonawców i utworów, w kolumnie C od komórki C2 w dół do komórki C101 (w każdym wierszu od góry do dołu) nazwa konta forumowicza, a w kolumnie D od komórki D2 w dół do komórki D101 punkty od 100 do 1.
Po tych danych jednego głosowania zrobiłem dwa wiersze przerwy i od komórek A103, B103, C103, D103 wrzucałem tak samo kolejne dane kolejnego głosowania. Po każdym zrobiłem dwa wiersze wolnego. Nie wiem czy to jest prawidłowe czy nie. Mam nadzieję, że się do tego ustosunkujesz. Wiem, że te dane zawierają błędy, które sam wychwyciłeś w postaci literówek, dubli, utworów spoza zestawu, a nawet braku jednej pozycji. Ale chciałem to zrobić podobnie jak Ty, żeby się zorientować jak program później sam wychwytuje te błędy. Wyszło mi, że zagłosowało 29 osób. To odnośnie pierwszego arkusza. Drugi arkusz w tym samym dokumencie nazwałem znowu tak jak Ty, czyli Top2023 wyniki. W kolumnie A od komórki A1 w dół do komórki A1006 robiąc kopiuj-wklej umieściłem wszystkie utwory z zestawu do głosowania. I tu znowu nie wiem czy postąpiłem prawidłowo umieszczając je od komórki A1 w dół, czy np. nie powinienem to zrobić od komórki A2. I na tym się na razie zatrzymałem, bo nie wiem co mam robić dalej. Napisałeś, że trzeba wkleić gdzieś formułę:

=SUMA.JEŻELI(Top2023glosy!B:B;A2;Top2023glosy!D:D)

Ale nie rozumiem konkretnie do której komórki i czy ta formuła odnosi się w ogóle do arkusza pierwszego, czy drugiego. Bo to co napisałeś, czyli: "powyższa funkcja znajduje się w innej kolumnie tego arkusza, w wierszu 2" w tym momencie niewiele mi mówi. Nadal nie wiem jak te pojedyńcze głosowania z pierwszego arkusza mogą w tym drugim zamienić się w gotowe wyniki nie wpisując ręcznie do pojedyńczych komórek punktów przypisanych do konkretnego utworu od każdego głosującego. Ale nadal wierzę, że wpisanie w jakąś konkretną komórkę odpowiedniej formuły i rozszerzenie jej na wszystkie kolumny przypisze w automacie do każdego konkretnego utworu punkty od każdego głosującego bez wklepywania tego ręcznie bo to zajęłoby z dobre kilka dni, a nie 2 godziny.

[mario85832719]

Pytanie jeszcze czy ta operacja się w ogóle powiedzie, jeśli w pierwszym formularzu będą błędy typu duble, piosenki spoza zestawu, brak pozycji lub literówki? Czy nie trzeba tych wszystkich 29 głosowań najpierw sprawdzić wpisując w kolumnę D odpowiedniej formuły i przeciągając ją później na wszystkie 100 wierszy do zbadania czy nie ma żadnych błędów. Jedną skuteczną formułę do badania dubli już mam.

SPRAWDZANIE DUPLIKATÓW

=JEŻELI(LICZ.JEŻELI($B$1:B1;B1)>1; "Duplikat"; "")

Jeżeli dajmy na to miałbym w komórce A1 nazwę utworu w tym drugim formularzu, a w komórkach B1, C, D1, itd., itd., itd.przypisane do niej punkty to potrafię je zsumować bez żadnego problemu za pomocą funkcji SUMA. Jednocześnie zsumować ze wszystkich 1006 wierszy też.

[VILKI]

nie rozumiem ani słowa z tego

[Miszon]

Otsotuchodzi xD .

[mario85832719]

nie rozumiem ani słowa z tego

Bo to bardziej przypomina taki informatyczny bełkot niż coś co mogłoby zainteresować

[neisej]

I tu znowu nie wiem czy postąpiłem prawidłowo umieszczając je od komórki A1 w dół, czy np. nie powinienem to zrobić od komórki A2.

Zawsze podaję by wpisać formułę w drugi wiersz bo w pierwszym wstawiam tytuły kolumn. Tytuły są dobre by widzieć co gdzie jest a poza tym jak się całą tabelę zaznaczy to można dodać autofiltr (chyba w menu "Dane > Filtr > Autofiltr") dzięki czemu można tymczasowo pokazać tylko część wierszy a resztę ukryć.

Na reszte pytań musze mieć czas by odpowiedzieć. Wiem co napisać ale chcę po kolei by się nie pogubić. I widzę,że te posty początkowe muszę po kolei uzupełnić ale na razie nie mam tyle czasu

Otsotuchodzi xD .

Pomysł jest taki by napisać krok po kroku napisać jak można zliczyć głosy w arkuszu kalkulacyjnym. mario85832719 jest tym zainteresowany ale może komuś też się to przyda

nie rozumiem ani słowa z tego

A chcesz zrozumieć?

[mario85832719]

I tu znowu nie wiem czy postąpiłem prawidłowo umieszczając je od komórki A1 w dół, czy np. nie powinienem to zrobić od komórki A2.

Zawsze podaję by wpisać formułę w drugi wiersz bo w pierwszym wstawiam tytuły kolumn. Tytuły są dobre by widzieć co gdzie jest a poza tym jak się całą tabelę zaznaczy to można dodać autofiltr (chyba w menu "Dane > Filtr > Autofiltr") dzięki czemu można tymczasowo pokazać tylko część wierszy a resztę ukryć.

Jeśli chcesz mieć lepszy pogląd na sprawę i wiedzieć więcej odnośnie funkcji, to możesz ściągnąć sobie też ten LibreOffice 7.6, który jest całkowicie darmowy, to może wtedy będzie Ci jeszcze zdecydowanie lepiej mi to wszystko wytłumaczyć. A później możesz go odinstalować.

[neisej]

Już mam pobrane ale nie mam kiedy zainstalować. Ale wyglada, że szukając online też się większość znajduje.

Wolne przrstrzenie mogą trochę przeszkadzać gdy się używa autofiltra ale jak sie np wszystko posortuje to i tak one zostaną na końcu.

Napisałeś, że trzeba wkleić gdzieś formułę:

=SUMA.JEŻELI(Top2023glosy!B:B;A2;Top2023glosy!D:D)

Ale nie rozumiem konkretnie do której komórki i czy ta formuła odnosi się w ogóle do arkusza pierwszego, czy drugiego. Bo to co napisałeś, czyli: "powyższa funkcja znajduje się w innej kolumnie tego arkusza, w wierszu 2" w tym momencie niewiele mi mówi.

Możesz np. do pierwszej wolnej w arkuszu Top2023wyniki (czyli chyba to będzie kolumna B - zaraz po liście utworów czyli komórka B2 i potem na całą kolumnę skopiować.

[neisej]

Jedną skuteczną formułę do badania dubli już mam.

SPRAWDZANIE DUPLIKATÓW

=JEŻELI(LICZ.JEŻELI($B$1:B1;B1)>1; "Duplikat"; "")

Jeżeli dajmy na to miałbym w komórce A1 nazwę utworu w tym drugim formularzu, a w komórkach B1, C, D1, itd., itd., itd.przypisane do niej punkty to potrafię je zsumować bez żadnego problemu za pomocą funkcji SUMA. Jednocześnie zsumować ze wszystkich 1006 wierszy też.

To działa przy założeniu, że w kolumnie są głosy tylko jednej osoby bo tylko uwzględnia utwór a powinno też osobę więc zamiast LICZ.JEŻELI raczej LICZ WARUNKI by było lepsze czyli:

=LICZ.WARUNKI($B$1:B1;B1;$C$1:C1;C1)

ewentualnie jeśli byś chciał by oznaczone były wszystkie wystąpienia duplikatów to formuła mogłaby być:

=LICZ.WARUNKI(B:B;B1;C:C;C1)

[mario85832719]

Możesz np. do pierwszej wolnej w arkuszu Top2023wyniki (czyli chyba to będzie kolumna B - zaraz po liście utworów czyli komórka B2 i potem na całą kolumnę skopiować.

Niestety po wklejeniu tej formuły do komórki B2 w drugim arkuszu Top2023wyniki i kliknięciu Enter w komórce B2 pojawia się:

#NAZWA?

Prawdopodobnie oznacza to, że wprowadziłłem niepoprawną nazwę funkcji lub komórki w formule.
Ewidetnie coś nie tak jest z arkuszem Top2023glosy. Tylko, co? Tak jak napisałem wcześniej te kolumny z każdym indywidualnym głosem na 100 utworów nie są ze sobą połączone, tylko każdy oddzielają dwa wiersze. To ma jakieś znaczenie, czy żadnego? A może ten błąd wyrzucił ze względu na to, że są tam błędy odnośnie dubli, literówek, itd., itd.?
A co by się stało, gdyby w pierwszym arkuszu było wszystko OK i formuła by była też adekwatna? Obok wierszy z utworami pojawiłyby się punkty?

[VILKI]

A chcesz zrozumieć?

też "bawię się" w liczenie i bardzo bym chciał zrozumieć ale chyba jestem za tępy

[mario85832719]

=LICZ.WARUNKI(B:B;B1;C:C;C1)

Formuła działa. Kiedy wszystko jest OK w komórkach w kolumnie E gdzie ją wkleiłem pojawia się cyfra 1, a jeśli jest dubel pojawia się 2. Na początku mi nie działała, ale zorientowałem się, że to była wina tego, że wkleiłem ją do komórki D2. A w formule jest odniesienie do pierwszego wiersza.
Ale przydałaby się oddzielna formuła, która sprawdziłaby jeszcze, czy nie ma dubli w kolumnie A. Bo może się tak zdarzyć, że ktoś przyporządkuje do dwóch utworów dwie takie same cyfry określające jej pozycje. Ale tu chyba sprawdzi się taka:

=LICZ.WARUNKI(A:A;A1;C:C;C1)

Już powoli zaczynam wszystko rozumieć, czemu w tak szybki sposób to wszystko udało Ci się sprawdzić, policzyć i przyporządkować do miejsc. Same poprawki zajęły więcej czasu, jeśli ktoś pomylił się z tego czy innego powodu głosując, bo tu już trzeba wszystko poprawiać wklepując ręcznie, bo nie da się już tego zrobić za pomocą formuł.

No to teraz znam już formułę zamieniającą lokaty na punkty, wychwytującą duble w kolumnie A i w kolumnie B, to teraz potrzebna mi jest jeszcze formuła wychwytująca brak jakiejś przypisanej pozycji, bo u jednego głosującego był brak pozycji 54 chyba, formuły, która wychwyci literówki. Ta formuła wychwytuje też nazwy utworów spoza zestawu do głosowania? To odnośnie pierwszego arkusza. A do drugiego potrzebna jest jeszcze formuła która przeniesie punkty od wszystkich głosujących z tego pierwszego i... Czy da się stworzyć formułę, która określa ranking uwzględniający że gdy oba utwory mają tyle samo punktów to wyżej będzie ten na którego oddano więcej głosów, a w następnym kroku który był na wyższej pozycji uwzględniając wszystkie oddane głosy? Czy to w ogóle możliwe?

[neisej]

Możesz np. do pierwszej wolnej w arkuszu Top2023wyniki (czyli chyba to będzie kolumna B - zaraz po liście utworów czyli komórka B2 i potem na całą kolumnę skopiować.

Niestety po wklejeniu tej formuły do komórki B2 w drugim arkuszu Top2023wyniki i kliknięciu Enter w komórce B2 pojawia się:

#NAZWA?

Prawdopodobnie oznacza to, że wprowadziłłem niepoprawną nazwę funkcji lub komórki w formule.
Ewidetnie coś nie tak jest z arkuszem Top2023glosy. Tylko, co? Tak jak napisałem wcześniej te kolumny z każdym indywidualnym głosem na 100 utworów nie są ze sobą połączone, tylko każdy oddzielają dwa wiersze. To ma jakieś znaczenie, czy żadnego? A może ten błąd wyrzucił ze względu na to, że są tam błędy odnośnie dubli, literówek, itd., itd.?
A co by się stało, gdyby w pierwszym arkuszu było wszystko OK i formuła by była też adekwatna? Obok wierszy z utworami pojawiłyby się punkty?

Może w nazwie arkusza masz spację albo "ł" zamiast "l"?. Jak to nazwa funkcji to može na liście funkcji będzie prawidłowa nazwa.
Chyba gdyby w sumowanych wartościach byłyby błędy to w wyniku byłby inny błąd (chyba #N/A) a jak będzie prawidłowo to będzie liczba - suma punktów dla odpowiedniego utworu.

też "bawię się" w liczenie i bardzo bym chciał zrozumieć ale chyba jestem za tępy

Nie za tępy tylko, trzeba od początku poznawać elementy. A jakiś formuł używasz przy podsumowywaniu czy tylko ręcznie wartości wpisujesz?

[mario85832719]

Może w nazwie arkusza masz spację albo "ł" zamiast "l"?. Jak to nazwa funkcji to može na liście funkcji będzie prawidłowa nazwa.

Oba arkusze nazwałem tak samo jak Ty bez żadnych spacji i polskich znaków, czyli Top2023glosy i Top2023wyniki.
Jak Ty sam nie znajdziesz rozwiązania czemu ta formuła jest nieskuteczna, to ja tego sam nie przeskoczę i będę musiał zakończyć tę swoją naukę, bo jeśli nie będę w stanie podsumować punktów to ta cała wykonana praca wcześniej jest tylko stratą czasu.

[VILKI]

Nie za tępy tylko, trzeba od początku poznawać elementy. A jakiś formuł używasz przy podsumowywaniu czy tylko ręcznie wartości wpisujesz?

wszystkie głosy wpisuje ręcznie a potem przyciskiem sumuje punkty każdego utworu po kolei

[neisej]

Może w nazwie arkusza masz spację albo "ł" zamiast "l"?. Jak to nazwa funkcji to može na liście funkcji będzie prawidłowa nazwa.

Oba arkusze nazwałem tak samo jak Ty bez żadnych spacji i polskich znaków, czyli Top2023glosy i Top2023wyniki.
Jak Ty sam nie znajdziesz rozwiązania czemu ta formuła jest nieskuteczna, to ja tego sam nie przeskoczę i będę musiał zakończyć tę swoją naukę, bo jeśli nie będę w stanie podsumować punktów to ta cała wykonana praca wcześniej jest tylko stratą czasu.

A czy ta formuła w Top2023wyniki działa:

Kod: Zaznacz cały

=LICZ.JEŻELI(Top2023glosy!B:B;A2)

?